VB のたまご

作成日: 2017/05/14, 更新日: 2017/05/14



DelegateCommand3

  •  引き続き、DelegateCommand です。 前回は、実行可否処理も含めた DelegateCommand を学習しました。 実行可否処理を再実行する際は、RaiseCanExecuteChanged メソッドを呼び出して再実行します。

  • Me.UpdateCommand.RaiseCanExecuteChanged()
    

    スポンサーリンク


  •  これでもいいんですが、再実行処理を離れたところに記載しなければいけないため、処理を追跡しづらい感じです。 これを良い感じに変えたものが以下です。以下は ViewModel のコンストラクタ内で、コマンドをインスタンス生成しているところです。

  • Me.UpdateCommand = New DelegateCommand(AddressOf Me.Update, AddressOf Me.CanUpdate)
    Me.UpdateCommand.ObservesProperty(Function() Me.HelloText)
    

  •  インスタンス生成した後で、ObservesProperty メソッドを使って、監視したいプロパティを指定します。 これを行うことで、RaiseCanExecuteChanged メソッドと同じ効果がありますし、離れたところに書くよりもこちらの方が処理を追跡しやすいというメリットがあります。

  •  今回のサンプルでは記載していませんが、ObservesProperty メソッドは重ね掛けすることができます。 つまり、Aの入力欄とBの入力欄が両方入力されている時だけ押せるコマンドにすることもできます。

  • Me.UpdateCommand.ObservesProperty(Function() Me.AText)
    Me.UpdateCommand.ObservesProperty(Function() Me.BText)
    

  •  このサンプルを実行すると、前回同様、入力欄へ1文字以上入力されている時だけボタンが押せて、何も入力していない時はボタンが押せなくなります。

  •  それでは、以下ソース全体です。
  •  今回は、WPF アプリケーションプロジェクトだけです。

  •  Window1ViewModel.vb

  • Imports Prism.Mvvm
    Imports Prism.Commands
    
    Namespace ViewModels
    
        Public Class Window1ViewModel
            Inherits BindableBase
    
            Private _HelloText As String
            Public Property HelloText() As String
                Get
                    Return _HelloText
                End Get
                Set(ByVal value As String)
                    Me.SetProperty(_HelloText, value)
                End Set
            End Property
    
            Public Property UpdateCommand As DelegateCommand
    
            ' コンストラクタ
            Public Sub New()
    
                ' ObservesProperty メソッドを使って、監視したいプロパティを指定する
                ' 指定プロパティの変更タイミングで、実行可否処理の再判断が行われる
                Me.UpdateCommand = New DelegateCommand(AddressOf Me.Update, AddressOf Me.CanUpdate)
                Me.UpdateCommand.ObservesProperty(Function() Me.HelloText)
    
            End Sub
    
            Private Sub Update()
    
                Console.WriteLine("Click!")
    
            End Sub
    
            Private Function CanUpdate() As Boolean
    
                Return Not String.IsNullOrWhiteSpace(Me.HelloText)
    
            End Function
    
        End Class
    
    End Namespace
    

  •  Window1.xaml
  •  画面クラスのコードビハインドには、名前空間の追加以外、処理はありません。

  • <Window x:Class="Views.Window1"
            xmlns="http://schemas.microsoft.com/winfx/2006/xaml/presentation"
            xmlns:x="http://schemas.microsoft.com/winfx/2006/xaml"
            xmlns:d="http://schemas.microsoft.com/expression/blend/2008"
            xmlns:mc="http://schemas.openxmlformats.org/markup-compatibility/2006"
            xmlns:local="clr-namespace:WpfApplication1.Views"
            xmlns:prism="http://prismlibrary.com/"
            prism:ViewModelLocator.AutoWireViewModel="True"
            mc:Ignorable="d"
            Title="Window1" Height="350" Width="525">
    
        <StackPanel>
    
            <TextBox Text="{Binding HelloText, UpdateSourceTrigger=PropertyChanged}" />
            <Button Content="更新" Command="{Binding UpdateCommand}" />
    
        </StackPanel>
        
    </Window>
    

  •  Bootstrapper.vb

  • Imports Microsoft.Practices.Unity
    Imports Prism.Unity
    Imports WpfApplication1.Views
    
    Public Class Bootstrapper
        Inherits UnityBootstrapper
    
        ' Shell 担当になる View のインスタンスを返却
        Protected Overrides Function CreateShell() As DependencyObject
            Return Me.Container.Resolve(Of Window1)
        End Function
    
        ' Shell 担当になる View を表示
        Protected Overrides Sub InitializeShell()
            Application.Current.MainWindow.Show()
        End Sub
    
    End Class
    

  •  Application.xaml.vb
  •  ※Application.xaml では、【StartupUri="MainWindow.xaml"】を削除しています。

  • Class Application
    
        ' Startup、Exit、DispatcherUnhandledException などのアプリケーション レベルのイベントは、
        ' このファイルで処理できます。
    
        Protected Overrides Sub OnStartup(e As StartupEventArgs)
            MyBase.OnStartup(e)
    
            ' Unity 管理による Prism アプリケーションの起動制御処理を実行
            Dim boot = New Bootstrapper
            boot.Run()
    
        End Sub
    
    End Class