VB のたまご

作成日: 2017/05/14, 更新日: 2017/05/14



DelegateCommand4

  •  引き続き、DelegateCommand です。 監視したいプロパティが Boolean 型に限り、専用の監視メソッドを使うことができます。 以下は、Boolean 型 の IsEnabled プロパティを監視するサンプルです。

  • Me.UpdateCommand = New DelegateCommand(AddressOf Me.Update)
    Me.UpdateCommand.ObservesCanExecute(Function() Me.IsEnabled)
    
    Private Sub Update()
    
        Console.WriteLine("Click!")
    
    End Sub
    

  •  この ObservesCanExecute メソッドには、Boolean 型のプロパティのみ指定することができます。 さらに、内部で CanExecute メソッドが生成&使用されて、かつ ObservesProperty メソッドと同じく IsEnabled プロパティを監視して、 値の変更があったタイミングで、実行可否処理を再判断してくれます。

  •  このサンプルを実行すると、チェック欄にチェックが付いている間だけ、ボタンを押すことができます。

  • スポンサーリンク


  •  それでは、以下ソース全体です。
  •  今回は、WPF アプリケーションプロジェクトだけです。

  •  Window1ViewModel.vb

  • Imports Prism.Mvvm
    Imports Prism.Commands
    
    Namespace ViewModels
    
        Public Class Window1ViewModel
            Inherits BindableBase
    
            Private _IsEnabled As Boolean
            Public Property IsEnabled() As Boolean
                Get
                    Return _IsEnabled
                End Get
                Set(ByVal value As Boolean)
                    Me.SetProperty(_IsEnabled, value)
                End Set
            End Property
    
            Public Property UpdateCommand As DelegateCommand
    
            ' コンストラクタ
            Public Sub New()
    
                ' ObservesCanExecute メソッドを使って、監視したいプロパティを指定する
                ' さらに、実行可否処理(CanUpdate メソッド)も自動的に生成&セットされる
                ' 指定プロパティの変更タイミングで、実行可否処理の再判断が行われる
                Me.UpdateCommand = New DelegateCommand(AddressOf Me.Update)
                Me.UpdateCommand.ObservesCanExecute(Function() Me.IsEnabled)
    
            End Sub
    
            Private Sub Update()
    
                Console.WriteLine("Click!")
    
            End Sub
    
        End Class
    
    End Namespace
    

  •  Window1.xaml
  •  画面クラスのコードビハインドには、名前空間の追加以外、処理はありません。

  • <Window x:Class="Views.Window1"
            xmlns="http://schemas.microsoft.com/winfx/2006/xaml/presentation"
            xmlns:x="http://schemas.microsoft.com/winfx/2006/xaml"
            xmlns:d="http://schemas.microsoft.com/expression/blend/2008"
            xmlns:mc="http://schemas.openxmlformats.org/markup-compatibility/2006"
            xmlns:local="clr-namespace:WpfApplication1.Views"
            xmlns:prism="http://prismlibrary.com/"
            prism:ViewModelLocator.AutoWireViewModel="True"
            mc:Ignorable="d"
            Title="Window1" Height="350" Width="525">
    
        <StackPanel>
    
            <!--<TextBox Text="{Binding HelloText, UpdateSourceTrigger=PropertyChanged}" />-->
            <CheckBox IsChecked="{Binding IsEnabled}" />
            <Button Content="更新" Command="{Binding UpdateCommand}" />
    
        </StackPanel>
        
    </Window>
    

  •  Bootstrapper.vb

  • Imports Microsoft.Practices.Unity
    Imports Prism.Unity
    Imports WpfApplication1.Views
    
    Public Class Bootstrapper
        Inherits UnityBootstrapper
    
        ' Shell 担当になる View のインスタンスを返却
        Protected Overrides Function CreateShell() As DependencyObject
            Return Me.Container.Resolve(Of Window1)
        End Function
    
        ' Shell 担当になる View を表示
        Protected Overrides Sub InitializeShell()
            Application.Current.MainWindow.Show()
        End Sub
    
    End Class
    

  •  Application.xaml.vb
  •  ※Application.xaml では、【StartupUri="MainWindow.xaml"】を削除しています。

  • Class Application
    
        ' Startup、Exit、DispatcherUnhandledException などのアプリケーション レベルのイベントは、
        ' このファイルで処理できます。
    
        Protected Overrides Sub OnStartup(e As StartupEventArgs)
            MyBase.OnStartup(e)
    
            ' Unity 管理による Prism アプリケーションの起動制御処理を実行
            Dim boot = New Bootstrapper
            boot.Run()
    
        End Sub
    
    End Class