VB のたまご

作成日: 2017/05/14, 更新日: 2017/05/14



DelegateCommand5

  •  引き続き、DelegateCommand です。 DelegateCommand には、引数を1つ受け取ることができるジェネリック版が用意されています。 以下では、View から文字列を受け取るコマンドを定義しています。

  • Public Property UpdateCommand As DelegateCommand(Of String)
    
    ' コンストラクタ
    Public Sub New()
    
        Me.UpdateCommand = New DelegateCommand(Of String)(AddressOf Me.Update)
    
    End Sub
    
    Private Sub Update(parameter As String)
    
        Me.HelloText = $"{parameter} / {DateTime.Now.ToString("HH:mm:ss.fff")}"
    
    End Sub
    

  •  このサンプルを実行すると、ボタンを押すたびに、View で渡したパラメータと押した時間を表示します。

  • スポンサーリンク


  •  それでは、以下ソース全体です。
  •  今回は、WPF アプリケーションプロジェクトだけです。

  •  Window1ViewModel.vb

  • Imports Prism.Mvvm
    Imports Prism.Commands
    
    Namespace ViewModels
    
        Public Class Window1ViewModel
            Inherits BindableBase
    
            Private _HelloText As String
            Public Property HelloText() As String
                Get
                    Return _HelloText
                End Get
                Set(ByVal value As String)
                    Me.SetProperty(_HelloText, value)
                End Set
            End Property
    
            Public Property UpdateCommand As DelegateCommand(Of String)
    
            ' コンストラクタ
            Public Sub New()
    
                Me.UpdateCommand = New DelegateCommand(Of String)(AddressOf Me.Update)
                Me.UpdateCommand.ObservesProperty(Function() Me.HelloText)
    
            End Sub
    
            Private Sub Update(parameter As String)
    
                Me.HelloText = $"{parameter} / {DateTime.Now.ToString("HH:mm:ss.fff")}"
    
            End Sub
    
        End Class
    
    End Namespace
    

  •  Window1.xaml
  •  画面クラスのコードビハインドには、名前空間の追加以外、処理はありません。

  • <Window x:Class="Views.Window1"
            xmlns="http://schemas.microsoft.com/winfx/2006/xaml/presentation"
            xmlns:x="http://schemas.microsoft.com/winfx/2006/xaml"
            xmlns:d="http://schemas.microsoft.com/expression/blend/2008"
            xmlns:mc="http://schemas.openxmlformats.org/markup-compatibility/2006"
            xmlns:local="clr-namespace:WpfApplication1.Views"
            xmlns:prism="http://prismlibrary.com/"
            prism:ViewModelLocator.AutoWireViewModel="True"
            mc:Ignorable="d"
            Title="Window1" Height="350" Width="525">
    
        <StackPanel>
    
            <TextBlock Text="{Binding HelloText}" />
            
            <Button 
                Content="更新" 
                Command="{Binding UpdateCommand}" 
                CommandParameter="テスト" />
    
        </StackPanel>
        
    </Window>
    

  •  Bootstrapper.vb

  • Imports Microsoft.Practices.Unity
    Imports Prism.Unity
    Imports WpfApplication1.Views
    
    Public Class Bootstrapper
        Inherits UnityBootstrapper
    
        ' Shell 担当になる View のインスタンスを返却
        Protected Overrides Function CreateShell() As DependencyObject
            Return Me.Container.Resolve(Of Window1)
        End Function
    
        ' Shell 担当になる View を表示
        Protected Overrides Sub InitializeShell()
            Application.Current.MainWindow.Show()
        End Sub
    
    End Class
    

  •  Application.xaml.vb
  •  ※Application.xaml では、【StartupUri="MainWindow.xaml"】を削除しています。

  • Class Application
    
        ' Startup、Exit、DispatcherUnhandledException などのアプリケーション レベルのイベントは、
        ' このファイルで処理できます。
    
        Protected Overrides Sub OnStartup(e As StartupEventArgs)
            MyBase.OnStartup(e)
    
            ' Unity 管理による Prism アプリケーションの起動制御処理を実行
            Dim boot = New Bootstrapper
            boot.Run()
    
        End Sub
    
    End Class