VB のたまご

作成日: 2017/05/14, 更新日: 2017/05/14



NotificationRequest

  •  NotificationRequest は、通知メッセージのことです。 通知は、ViewModel が必要なデータを準備して、メッセージ表示の依頼を View に指示します。 View は依頼されたことをトリガーアクションとして実行します。メッセージ処理は連携処理で成り立っています。

  • イメージ
    スポンサーリンク


  •  それでは、コードです。 通知依頼をおこなうには、Prism.Interactivity.InteractionRequest.InteractionRequest クラスを使います。 今回は、情報メッセージ(返事を必要としない)を表示したいので、ジェネリック引数には、INotification インターフェースを指定します。 後は、インスタンス生成して、依頼をかけるときにメッセージ文言を渡すだけです。

  • Public Property RequestMessage As InteractionRequest(Of INotification)
    Public Property RequestCommand As DelegateCommand
    
    ' コンストラクタ
    Public Sub New()
    
        Me.RequestMessage = New InteractionRequest(Of INotification)
        Me.RequestCommand = New DelegateCommand(AddressOf Me.ShowMessage)
    
    End Sub
    
    Private Sub ShowMessage()
    
        Dim message = New Notification With {.Title = "通知", .Content = "通知メッセージです"}
        Me.RequestMessage.Raise(message, Sub(x) Me.Title = "通知しました")
    
    End Sub
    

  •  View では、RequestMessage プロパティをバインドしており、依頼を感知します。 依頼を受けたら、PopupWindowAction アクションを通してメッセージボックスを表示します。 ここではオプション設定で、モーダル形式で、呼び出し元画面の中央にメッセージボックスを表示するように指示しています。 ちなみに、InteractionTrigger を使うため、名前空間タグには、【xmlns:i="http://schemas.microsoft.com/expression/2010/interactivity"】を追加するのを忘れないでください。

  • <i:Interaction.Triggers>
    
        <prism:InteractionRequestTrigger SourceObject="{Binding RequestMessage}">
            <prism:PopupWindowAction IsModal="True" CenterOverAssociatedObject="True" />
        </prism:InteractionRequestTrigger>
    
    </i:Interaction.Triggers>
    

  •  このサンプルを実行すると、ボタンが表示されるので、ボタンを押すと情報メッセージが表示されます。

  • スポンサーリンク


  •  それでは、以下ソース全体です。
  •  今回は、WPF アプリケーションプロジェクトだけです。

  •  Window1ViewModel.vb

  • Imports Prism.Mvvm
    Imports Prism.Commands
    Imports Prism.Interactivity.InteractionRequest
    
    Namespace ViewModels
    
        ' メッセージボックスは、ViewModel で InteractionRequest クラスの準備(依頼の指示)、
        ' View で InteractionRequestTrigger トリガー&アクションを準備(依頼された画面の表示)して、
        ' 2つの組み合わせで表示します
    
        Public Class Window1ViewModel
            Inherits BindableBase
    
            Private _Title As String
            Public Property Title() As String
                Get
                    Return _Title
                End Get
                Set(ByVal value As String)
                    Me.SetProperty(_Title, value)
                End Set
            End Property
    
            Public Property RequestMessage As InteractionRequest(Of INotification)
            Public Property RequestCommand As DelegateCommand
    
            ' コンストラクタ
            Public Sub New()
    
                Me.Title = "Prism Unity Application"
                Me.RequestMessage = New InteractionRequest(Of INotification)
                Me.RequestCommand = New DelegateCommand(AddressOf Me.ShowMessage)
    
            End Sub
    
            Private Sub ShowMessage()
    
                Dim message = New Notification With {.Title = "通知", .Content = "通知メッセージです"}
                Me.RequestMessage.Raise(message, Sub(x) Me.Title = "通知しました")
    
            End Sub
    
        End Class
    
    End Namespace
    

  •  Window1.xaml
  •  画面クラスのコードビハインドには、名前空間の追加以外、処理はありません。

  • <Window x:Class="Views.Window1"
            xmlns="http://schemas.microsoft.com/winfx/2006/xaml/presentation"
            xmlns:x="http://schemas.microsoft.com/winfx/2006/xaml"
            xmlns:d="http://schemas.microsoft.com/expression/blend/2008"
            xmlns:mc="http://schemas.openxmlformats.org/markup-compatibility/2006"
            xmlns:local="clr-namespace:WpfApplication1.Views"
            xmlns:prism="http://prismlibrary.com/"
            prism:ViewModelLocator.AutoWireViewModel="True"
            xmlns:i="http://schemas.microsoft.com/expression/2010/interactivity"
            mc:Ignorable="d"
            Title="{Binding Title}" Height="350" Width="525">
    
        <!-- 要求を受けて、通知メッセージを表示する。モーダル形式の表示方法で、親画面の中央に表示する -->
        <i:Interaction.Triggers>
    
            <prism:InteractionRequestTrigger SourceObject="{Binding RequestMessage}">
                <prism:PopupWindowAction IsModal="True" CenterOverAssociatedObject="True" />
            </prism:InteractionRequestTrigger>
    
        </i:Interaction.Triggers>
    
        <!-- 画面 -->
        <StackPanel>
    
            <Button Content="button1" Command="{Binding RequestCommand}" />
            <TextBlock Text="{Binding Title}" />
    
        </StackPanel>
    
    </Window>
    

  •  Bootstrapper.vb

  • Imports Microsoft.Practices.Unity
    Imports Prism.Unity
    Imports Prism.Modularity
    Imports WpfApplication1.Views
    
    Public Class Bootstrapper
        Inherits UnityBootstrapper
    
        ' Shell 担当になる View のインスタンスを返却
        Protected Overrides Function CreateShell() As DependencyObject
            Return Me.Container.Resolve(Of Window1)
        End Function
    
        ' Shell 担当になる View を表示
        Protected Overrides Sub InitializeShell()
            Application.Current.MainWindow.Show()
        End Sub
    
    End Class
    

  •  Application.xaml.vb
  •  ※Application.xaml では、【StartupUri="MainWindow.xaml"】を削除しています。

  • Class Application
    
        ' Startup、Exit、DispatcherUnhandledException などのアプリケーション レベルのイベントは、
        ' このファイルで処理できます。
    
        Protected Overrides Sub OnStartup(e As StartupEventArgs)
            MyBase.OnStartup(e)
    
            ' Unity 管理による Prism アプリケーションの起動制御処理を実行
            Dim boot = New Bootstrapper
            boot.Run()
    
        End Sub
    
    End Class