VB のたまご

作成日: 2017/05/14, 更新日: 2017/05/14



Navigation3

  •  引き続き、Navigation です。
  •  画面1を表示して、画面2に切り替えた後、画面1に戻した時に、画面1が以前の表示状態だと自然ですよね。 また、遷移した時に DB からデータ取得や表示設定をしたり、逆に別の画面に遷移するため、画面から離れる時に DB にデータ更新を行いたいというのは一般的なシナリオですね。

  •  このように、遷移処理時のインスタンス管理や遷移時の専用処理を行うためには、Prism.Regions.INavigationAware インターフェースを実装します。

  •  まず、一度インスタンス生成した画面を再利用して使うかどうかを判定するには IsNavigationTarget メソッドを使います。 True なら再利用する、False ならインスタンスを新規作成する(別画面として扱う)という選択ができます。

  • ' 遷移先の画面として本画面のインスタンスを再利用するかどうか
    ' true: 本画面のインスタンスを再利用して表示、別インスタンスとして本画面を表示
    Public Function IsNavigationTarget(navigationContext As NavigationContext) As Boolean Implements INavigationAware.IsNavigationTarget
        Console.WriteLine("AViewModel - IsNavigationTarget")
        Return True
    End Function
    

  •  続いて、遷移時に何らかの処理をおこなうためには OnNavigatedTo メソッドを使います。 ここでは、何回この画面に遷移してきたかのカウンター PageViews をインクリメントしていますね。

  • ' 本画面に遷移する時の処理
    Public Sub OnNavigatedTo(navigationContext As NavigationContext) Implements INavigationAware.OnNavigatedTo
        Console.WriteLine("AViewModel - OnNavigatedTo")
        Me.PageViews += 1
    End Sub
    

  •  最後に、画面から離れる時に何らかの処理をおこなうためには OnNavigatedFrom メソッドを使います。

  • ' 本画面から離れる時の処理
    Public Sub OnNavigatedFrom(navigationContext As NavigationContext) Implements INavigationAware.OnNavigatedFrom
        Console.WriteLine("AViewModel - OnNavigatedFrom")
    End Sub
    

  •  Console.WriteLine メソッドは、処理の追跡用に書いたものなので消してしまって構いません。 このサンプルを実行すると、それぞれの画面に遷移するボタンが表示されています。 ボタンを押すたびに、その画面が表示されかつ何回遷移したかのカウンターが更新されて表示されます。

  • スポンサーリンク


  •  それでは、以下ソース全体です。

  •  切り替える画像を管理するプロジェクト(クラスライブラリ)

  •  AViewModel.vb

  • Imports Prism.Mvvm
    Imports Prism.Regions
    
    Namespace ViewModels
    
        Public Class AViewModel
            Inherits BindableBase
            Implements INavigationAware
    
            Private _Title As String = "View A"
            Public Property Title() As String
                Get
                    Return _Title
                End Get
                Set(ByVal value As String)
                    Me.SetProperty(_Title, value)
                End Set
            End Property
    
            Private _PageViews As Integer
            Public Property PageViews() As Integer
                Get
                    Return _PageViews
                End Get
                Set(ByVal value As Integer)
                    Me.SetProperty(_PageViews, value)
                End Set
            End Property
    
            ' 本画面から離れる時の処理
            Public Sub OnNavigatedFrom(navigationContext As NavigationContext) Implements INavigationAware.OnNavigatedFrom
                Console.WriteLine("AViewModel - OnNavigatedFrom")
            End Sub
    
            ' 本画面に遷移する時の処理
            Public Sub OnNavigatedTo(navigationContext As NavigationContext) Implements INavigationAware.OnNavigatedTo
                Console.WriteLine("AViewModel - OnNavigatedTo")
                Me.PageViews += 1
            End Sub
    
            ' 遷移先の画面として本画面のインスタンスを再利用するかどうか
            ' true: 本画面のインスタンスを再利用して表示、別インスタンスとして本画面を表示
            Public Function IsNavigationTarget(navigationContext As NavigationContext) As Boolean Implements INavigationAware.IsNavigationTarget
                Console.WriteLine("AViewModel - IsNavigationTarget")
                Return True
            End Function
    
        End Class
    
    End Namespace
    

  •  BViewModel.vb
  •  BViewModel も AViewModel と同じ動作だとつまらないと思うので、IsNavigationTarget メソッドでは、False を返すように処理を変更すると、 プログラム実行時に、よりこのメソッドの効果を理解することができます。

  • Imports Prism.Mvvm
    Imports Prism.Regions
    
    Namespace ViewModels
    
        Public Class BViewModel
            Inherits BindableBase
            Implements INavigationAware
    
            Private _Title As String = "View B"
            Public Property Title() As String
                Get
                    Return _Title
                End Get
                Set(ByVal value As String)
                    Me.SetProperty(_Title, value)
                End Set
            End Property
    
            Private _PageViews As Integer
            Public Property PageViews() As Integer
                Get
                    Return _PageViews
                End Get
                Set(ByVal value As Integer)
                    Me.SetProperty(_PageViews, value)
                End Set
            End Property
    
            ' 本画面から離れる時の処理
            Public Sub OnNavigatedFrom(navigationContext As NavigationContext) Implements INavigationAware.OnNavigatedFrom
                Console.WriteLine("BViewModel - OnNavigatedFrom")
            End Sub
    
            ' 本画面に遷移する時の処理
            Public Sub OnNavigatedTo(navigationContext As NavigationContext) Implements INavigationAware.OnNavigatedTo
                Console.WriteLine("BViewModel - OnNavigatedTo")
                Me.PageViews += 1
            End Sub
    
            ' 遷移先の画面として本画面のインスタンスを再利用するかどうか
            ' true: 本画面のインスタンスを再利用して表示、別インスタンスとして本画面を表示
            Public Function IsNavigationTarget(navigationContext As NavigationContext) As Boolean Implements INavigationAware.IsNavigationTarget
                Console.WriteLine("BViewModel - IsNavigationTarget")
                Return True
            End Function
    
        End Class
    
    End Namespace
    

  •  AView.xaml
  •  画面クラスのコードビハインドには、名前空間の追加以外、処理はありません。

  • <UserControl x:Class="Views.AView"
                 xmlns="http://schemas.microsoft.com/winfx/2006/xaml/presentation"
                 xmlns:x="http://schemas.microsoft.com/winfx/2006/xaml"
                 xmlns:mc="http://schemas.openxmlformats.org/markup-compatibility/2006" 
                 xmlns:d="http://schemas.microsoft.com/expression/blend/2008" 
                 xmlns:local="clr-namespace:ClassLibrary1.Views"
                 xmlns:prism="http://prismlibrary.com/"
                 prism:ViewModelLocator.AutoWireViewModel="True"
                 mc:Ignorable="d" 
                 d:DesignHeight="300" d:DesignWidth="300">
    
        <StackPanel>
            <TextBlock Text="{Binding Title}" FontSize="48" HorizontalAlignment="Center" VerticalAlignment="Center" />
            <TextBlock Text="{Binding PageViews}" FontSize="24" HorizontalAlignment="Center" VerticalAlignment="Center" />
        </StackPanel>
    
    </UserControl>
    

  •  BView.xaml
  •  画面クラスのコードビハインドには、名前空間の追加以外、処理はありません。

  • <UserControl x:Class="Views.BView"
                 xmlns="http://schemas.microsoft.com/winfx/2006/xaml/presentation"
                 xmlns:x="http://schemas.microsoft.com/winfx/2006/xaml"
                 xmlns:mc="http://schemas.openxmlformats.org/markup-compatibility/2006" 
                 xmlns:d="http://schemas.microsoft.com/expression/blend/2008" 
                 xmlns:local="clr-namespace:ClassLibrary1.Views"
                 xmlns:prism="http://prismlibrary.com/"
                 prism:ViewModelLocator.AutoWireViewModel="True"
                 mc:Ignorable="d" 
                 d:DesignHeight="300" d:DesignWidth="300">
        
        <StackPanel>
            <TextBlock Text="{Binding Title}" FontSize="48" HorizontalAlignment="Center" VerticalAlignment="Center" />
            <TextBlock Text="{Binding PageViews}" FontSize="24" HorizontalAlignment="Center" VerticalAlignment="Center" />
        </StackPanel>
        
    </UserControl>
    

  •  ClassLibrary1Module.vb

  • Imports Microsoft.Practices.Unity
    Imports Prism.Unity
    Imports Prism.Regions
    Imports Prism.Modularity
    Imports ClassLibrary1.Views
    
    Public Class ClassLibrary1Module
        Implements IModule
    
        <Dependency>
        Public Property Container As IUnityContainer
    
        Public Sub Initialize() Implements IModule.Initialize
    
            Me.Container.RegisterTypeForNavigation(Of AView)()
            Me.Container.RegisterTypeForNavigation(Of BView)()
    
        End Sub
    
    End Class
    

    スポンサーリンク


  •  続いて、WPF アプリケーションプロジェクト

  •  Window1ViewModel.vb

  • Imports Microsoft.Practices.Unity ' Dependency 属性
    Imports Prism.Mvvm
    Imports Prism.Commands
    Imports Prism.Regions
    
    Namespace ViewModels
    
        Public Class Window1ViewModel
            Inherits BindableBase
    
            Private _Title As String = "Prism Unity Application"
            Public Property Title() As String
                Get
                    Return _Title
                End Get
                Set(ByVal value As String)
                    _Title = value
                End Set
            End Property
    
            Public Property NavigateCommand As DelegateCommand(Of String)
    
            <Dependency>
            Public Property Manager As IRegionManager
    
            Public Sub New()
                Me.NavigateCommand = New DelegateCommand(Of String)(AddressOf Me.Navigate)
            End Sub
    
            ' 画面を遷移
            Private Sub Navigate(viewName As String)
    
                If Not String.IsNullOrWhiteSpace(viewName) Then
                    Me.Manager.RequestNavigate("ContentRegion", viewName, AddressOf Me.NavigationComplete)
                End If
    
            End Sub
    
            ' 遷移完了後処理
            Private Sub NavigationComplete(result As NavigationResult)
                Console.WriteLine($"Window1ViewModel - Navigation to {result.Context.Uri} complete. / {DateTime.Now.ToString("HH:mm:ss.fff")}")
            End Sub
    
        End Class
    
    End Namespace
    

  •  Window1.xaml
  •  画面クラスのコードビハインドには、名前空間の追加以外、処理はありません。

  • <Window x:Class="Views.Window1"
            xmlns="http://schemas.microsoft.com/winfx/2006/xaml/presentation"
            xmlns:x="http://schemas.microsoft.com/winfx/2006/xaml"
            xmlns:d="http://schemas.microsoft.com/expression/blend/2008"
            xmlns:mc="http://schemas.openxmlformats.org/markup-compatibility/2006"
            xmlns:local="clr-namespace:WpfApplication1.Views"
            xmlns:prism="http://prismlibrary.com/"
            prism:ViewModelLocator.AutoWireViewModel="True"
            mc:Ignorable="d"
            Title="{Binding Title}" Height="350" Width="525">
    
        <Window.Resources>
            <Style TargetType="TabItem">
                <Setter Property="Header" Value="{Binding DataContext.Title}" />
            </Style>
        </Window.Resources>
        
        <DockPanel LastChildFill="True">
    
            <StackPanel Orientation="Horizontal" DockPanel.Dock="Top" Margin="5">
                
                <Button 
                    Content="AView へ遷移" 
                    Command="{Binding NavigateCommand}" 
                    CommandParameter="AView" 
                    Margin="5" />
    
                <Button 
                    Content="BView へ遷移" 
                    Command="{Binding NavigateCommand}" 
                    CommandParameter="BView" 
                    Margin="5" />
    
            </StackPanel>
    
            <TabControl 
                prism:RegionManager.RegionName="ContentRegion"
                Margin="5" />
    
        </DockPanel>
    
    </Window>
    

  •  Bootstrapper.vb

  • Imports Microsoft.Practices.Unity
    Imports Prism.Unity
    Imports Prism.Modularity
    Imports WpfApplication1.Views
    Imports ClassLibrary1
    
    Public Class Bootstrapper
        Inherits UnityBootstrapper
    
        ' Shell 担当になる View のインスタンスを返却
        Protected Overrides Function CreateShell() As DependencyObject
            Return Me.Container.Resolve(Of Window1)
        End Function
    
        ' Shell 担当になる View を表示
        Protected Overrides Sub InitializeShell()
            Application.Current.MainWindow.Show()
        End Sub
    
        ' モジュールカタログにモジュール情報を登録
        Protected Overrides Sub ConfigureModuleCatalog()
    
            Dim catalog = CType(Me.ModuleCatalog, ModuleCatalog)
            catalog.AddModule(GetType(ClassLibrary1Module))
    
        End Sub
    
    End Class
    

  •  Application.xaml.vb
  •  ※Application.xaml では、【StartupUri="MainWindow.xaml"】を削除しています。

  • Class Application
    
        ' Startup、Exit、DispatcherUnhandledException などのアプリケーション レベルのイベントは、
        ' このファイルで処理できます。
    
        Protected Overrides Sub OnStartup(e As StartupEventArgs)
            MyBase.OnStartup(e)
    
            ' Unity 管理による Prism アプリケーションの起動制御処理を実行
            Dim boot = New Bootstrapper
            boot.Run()
    
        End Sub
    
    End Class