VB のたまご

作成日: 2017/05/14, 更新日: 2017/05/14



Navigation5

  •  引き続き、Navigation です。 ここでは、画面遷移前に引き留める方法を学習します。

  •  画面内にある入力必須項目で、未入力の項目がある、または変更された項目があり保存するかどうか確認したい時など、 遷移前に、遷移有無判定を行いたい時があります。例えばこのようなシナリオではメッセージボックスなど表示して、 破棄していいか、保存した方がいいかを確認取りたいです。

  •  それではコードを見てみましょう。

  •  今回は、切り替え画面をバインドしている ViewModel 内に機能を付け加えます。 この機能は、Prism.Regions.IConfirmNavigationRequest インターフェースを実装して作成します。

  •  IConfirmNavigationRequest インターフェースは、INavigationAware インターフェースを継承していて、 INavigationAware の機能に加えて、遷移処理の確認をする機能が追加されています。

  •  このサンプルでは、画面から離れる時に、メッセージボックスを表示して、本当に遷移してもいいか確認しています。

  • Public Sub ConfirmNavigationRequest(navigationContext As NavigationContext, continuationCallback As Action(Of Boolean)) Implements IConfirmNavigationRequest.ConfirmNavigationRequest
    
        Dim goNavigation = True
    
        ' VM 内で、直接 View を扱っていますが気にしないでください
        If MessageBox.Show("このまま遷移しますか?", "確認", MessageBoxButton.YesNo) = MessageBoxResult.No Then
            goNavigation = False
        End If
    
        continuationCallback(goNavigation)
    
    End Sub
    

  •  continuationCallback というアクションに False をセットして実行すると、 遷移処理がキャンセルされ、現在の画面内にとどまることができます。

  •  このサンプルを実行すると、ボタンが2つ表示されており、それぞれの画面を表示することができます。 ただし、AView を表示中に、BView を表示しようとすると確認メッセージが表示されます。 「はい」を選ぶと BView に遷移して、「いいえ」を選ぶと AView にとどまります。

  • スポンサーリンク


  •  それでは、以下ソース全体です。

  •  クラスライブラリプロジェクト

  •  AViewModel.vb

  • Imports Prism.Mvvm
    Imports Prism.Regions
    Imports System.Windows
    
    Namespace ViewModels
    
        Public Class AViewModel
            Inherits BindableBase
            Implements IConfirmNavigationRequest ' INavigationAware から変更
    
            Public Sub ConfirmNavigationRequest(navigationContext As NavigationContext, continuationCallback As Action(Of Boolean)) Implements IConfirmNavigationRequest.ConfirmNavigationRequest
    
                Dim goNavigation = True
    
                ' VM 内で、直接 View を扱っていますが気にしないでください
                If MessageBox.Show("このまま遷移しますか?", "確認", MessageBoxButton.YesNo) = MessageBoxResult.No Then
                    goNavigation = False
                End If
    
                continuationCallback(goNavigation)
    
            End Sub
    
            ' 遷移先の画面として本画面のインスタンスを再利用するかどうか
            ' true: 本画面のインスタンスを再利用して表示、別インスタンスとして本画面を表示
            Public Function IsNavigationTarget(navigationContext As NavigationContext) As Boolean Implements INavigationAware.IsNavigationTarget
                Return True
            End Function
    
            ' 本画面に遷移する時の処理
            Public Sub OnNavigatedTo(navigationContext As NavigationContext) Implements INavigationAware.OnNavigatedTo
    
            End Sub
    
            ' 本画面から離れる時の処理
            Public Sub OnNavigatedFrom(navigationContext As NavigationContext) Implements INavigationAware.OnNavigatedFrom
    
            End Sub
    
        End Class
    
    End Namespace
    

  •  BViewModel.vb

  • Imports Prism.Mvvm
    
    Namespace ViewModels
    
        Public Class BViewModel
            Inherits BindableBase
    
        End Class
    
    End Namespace
    

  •  AView.xaml
  •  画面クラスのコードビハインドには、名前空間の追加以外、処理はありません。

  • <UserControl x:Class="Views.AView"
                 xmlns="http://schemas.microsoft.com/winfx/2006/xaml/presentation"
                 xmlns:x="http://schemas.microsoft.com/winfx/2006/xaml"
                 xmlns:mc="http://schemas.openxmlformats.org/markup-compatibility/2006" 
                 xmlns:d="http://schemas.microsoft.com/expression/blend/2008" 
                 xmlns:local="clr-namespace:ClassLibrary1.Views"
                 xmlns:prism="http://prismlibrary.com/"
                 prism:ViewModelLocator.AutoWireViewModel="True"
                 mc:Ignorable="d" 
                 d:DesignHeight="300" d:DesignWidth="300">
    
        <Grid>
            <TextBlock Text="View A" FontSize="48" HorizontalAlignment="Center" VerticalAlignment="Center" />
        </Grid>
    
    </UserControl>
    

  •  BView.xaml
  •  画面クラスのコードビハインドには、名前空間の追加以外、処理はありません。

  • <UserControl x:Class="Views.BView"
                 xmlns="http://schemas.microsoft.com/winfx/2006/xaml/presentation"
                 xmlns:x="http://schemas.microsoft.com/winfx/2006/xaml"
                 xmlns:mc="http://schemas.openxmlformats.org/markup-compatibility/2006" 
                 xmlns:d="http://schemas.microsoft.com/expression/blend/2008" 
                 xmlns:local="clr-namespace:ClassLibrary1.Views"
                 xmlns:prism="http://prismlibrary.com/"
                 prism:ViewModelLocator.AutoWireViewModel="True"
                 mc:Ignorable="d" 
                 d:DesignHeight="300" d:DesignWidth="300">
    
        <Grid>
            <TextBlock Text="View B" FontSize="48" HorizontalAlignment="Center" VerticalAlignment="Center" />
        </Grid>
        
    </UserControl>
    

  •  ClassLibrary1Module.vb

  • Imports Microsoft.Practices.Unity
    Imports Prism.Unity
    Imports Prism.Regions
    Imports Prism.Modularity
    Imports ClassLibrary1.Views
    
    Public Class ClassLibrary1Module
        Implements IModule
    
        <Dependency>
        Public Property Container As IUnityContainer
    
        Public Sub Initialize() Implements IModule.Initialize
    
            Me.Container.RegisterTypeForNavigation(Of AView)()
            Me.Container.RegisterTypeForNavigation(Of BView)()
    
        End Sub
    
    End Class
    

    スポンサーリンク


  •  WPF アプリケーションプロジェクト

  •  Window1ViewModel.vb

  • Imports Microsoft.Practices.Unity ' Dependency 属性
    Imports Prism.Mvvm
    Imports Prism.Commands
    Imports Prism.Regions
    
    Namespace ViewModels
    
        Public Class Window1ViewModel
            Inherits BindableBase
    
            Private _Title As String = "Prism Unity Application"
            Public Property Title() As String
                Get
                    Return _Title
                End Get
                Set(ByVal value As String)
                    _Title = value
                End Set
            End Property
    
            Public Property NavigateCommand As DelegateCommand(Of String)
    
            <Dependency>
            Public Property Manager As IRegionManager
    
            ' コンストラクタ
            Public Sub New()
                Me.NavigateCommand = New DelegateCommand(Of String)(AddressOf Me.Navigate)
            End Sub
    
            ' 画面を遷移
            Private Sub Navigate(viewName As String)
    
                If Not String.IsNullOrWhiteSpace(viewName) Then
                    Me.Manager.RequestNavigate("ContentRegion", viewName)
                End If
    
            End Sub
    
        End Class
    
    End Namespace
    

  •  Window1.xaml
  •  画面クラスのコードビハインドには、名前空間の追加以外、処理はありません。

  • <Window x:Class="Views.Window1"
            xmlns="http://schemas.microsoft.com/winfx/2006/xaml/presentation"
            xmlns:x="http://schemas.microsoft.com/winfx/2006/xaml"
            xmlns:d="http://schemas.microsoft.com/expression/blend/2008"
            xmlns:mc="http://schemas.openxmlformats.org/markup-compatibility/2006"
            xmlns:local="clr-namespace:WpfApplication1.Views"
            xmlns:prism="http://prismlibrary.com/"
            prism:ViewModelLocator.AutoWireViewModel="True"
            mc:Ignorable="d"
            Title="{Binding Title}" Height="350" Width="525">
    
        <DockPanel LastChildFill="True">
    
            <StackPanel Orientation="Horizontal" DockPanel.Dock="Top" Margin="5">
                
                <Button 
                    Content="AView へ遷移" 
                    Command="{Binding NavigateCommand}" 
                    CommandParameter="AView" 
                    Margin="5" />
    
                <Button 
                    Content="BView へ遷移" 
                    Command="{Binding NavigateCommand}" 
                    CommandParameter="BView" 
                    Margin="5" />
    
            </StackPanel>
    
            <ContentControl 
                prism:RegionManager.RegionName="ContentRegion"
                Margin="5" />
    
        </DockPanel>
    
    </Window>
    

  •  Bootstrapper.vb

  • Imports Microsoft.Practices.Unity
    Imports Prism.Unity
    Imports Prism.Modularity
    Imports WpfApplication1.Views
    Imports ClassLibrary1
    
    Public Class Bootstrapper
        Inherits UnityBootstrapper
    
        ' Shell 担当になる View のインスタンスを返却
        Protected Overrides Function CreateShell() As DependencyObject
            Return Me.Container.Resolve(Of Window1)
        End Function
    
        ' Shell 担当になる View を表示
        Protected Overrides Sub InitializeShell()
            Application.Current.MainWindow.Show()
        End Sub
    
        ' モジュールカタログにモジュール情報を登録
        Protected Overrides Sub ConfigureModuleCatalog()
    
            Dim catalog = CType(Me.ModuleCatalog, ModuleCatalog)
            catalog.AddModule(GetType(ClassLibrary1Module))
    
        End Sub
    
    End Class
    

  •  Application.xaml.vb
  •  ※Application.xaml では、【StartupUri="MainWindow.xaml"】を削除しています。

  • Class Application
    
        ' Startup、Exit、DispatcherUnhandledException などのアプリケーション レベルのイベントは、
        ' このファイルで処理できます。
    
        Protected Overrides Sub OnStartup(e As StartupEventArgs)
            MyBase.OnStartup(e)
    
            ' Unity 管理による Prism アプリケーションの起動制御処理を実行
            Dim boot = New Bootstrapper
            boot.Run()
    
        End Sub
    
    End Class